Boite aux lettres mains libres

Groupe 4

Anaëlle ATTALI, Noan PUNGIER, Ines REKIK, Anna DJENNO

Objectifs

Il n’est pas toujours facile de mettre la main sur ses clefs de boite aux lettres !
On n’a déjà plus besoin de clefs pour ouvrir et démarrer sa voiture …
Pourquoi la boite aux lettres ferait-elle exception ?

L’objectif de ce projet est donc de concevoir un dispositif d’ouverture automatique d’une boite aux lettres :

• L’utilisateur approche une carte d’accès RFID
• La boite aux lettres s’ouvre
• L’utilisateur referme la boite en repoussant simplement la porte

Moyens

• Une boite aux lettres standard (avec maquette numérique Solidworks : Boite_aux_lettres_SW ou bien Boite_aux_lettres_SW2013)
• Microcontrôleur Arduino
• Shield NFC/RFID
• Servomoteur
• Impression 3D des pièces mécaniques

Réalisation

Conception d’un mécanisme à poulies+courroie crantée pour l’ouverture de la porte :

Mais cette solution s’est avérée non satisfaisante car en raison du couple important à transmettre, il fallait tendre la courroie très fort, ce qui tordait la porte !

Il a donc fallu reconcevoir le système de transmission, avec un engrenage cette fois ci :

Conception d’un mécanisme à pignon + secteur denté

Maquette numérique complète

Boite_aux_lettres_SW_complete (SW2017)

Boite_aux_lettres_SW_avec engrenage (SW2013)

Programme Arduino

#include <SPI.h>
#include "PN532_SPI.h"
#include "PN532.h"
#include "NfcAdapter.h"
#include <Servo.h>
#include <FlexiTimer2.h>
 
String const myUID = "DD 4A 61 94"; // UID de la carte "autorisée"
int const LedPin = 13;              // port de la LED témoin
int const ServoPin = 9;             // port du servomoteur

PN532_SPI interface(SPI, 10);
NfcAdapter nfc = NfcAdapter(interface);

// Pour éviter les "rebonds" du bouton
unsigned long lastDebounceTime = 0;  // the last time the output pin was toggled
unsigned long debounceDelay = 100;    // the debounce time; increase if the output flickers

// Le servomoteur pour ouvrir/fermer la serrure
Servo monServo;
 
 
void setup(void) {
   Serial.begin(115200);
   Serial.println("NDEF Reader");
   nfc.begin();

   pinMode(LedPin,OUTPUT);
   digitalWrite(LedPin,LOW);
   
   // Interruption pour le bouton poussoir (sur port 2)
   attachInterrupt(0, fermer, FALLING);
     
   // Servomoteur
   monServo.attach(ServoPin);  // relier le servomoteur au port 9 
   monServo.write(0);  // positionner le servomoteur à l'angle absolu 90°
   
   // Mise en place d'un timer (2s) pour contrôler l'extinction du servomoteur
   FlexiTimer2::set(2000, pause);
   FlexiTimer2::start();
}
 
void loop(void) {
   Serial.println("Scanning...");
   if (nfc.tagPresent()) // check if an NFC tag is present on the antenna area
   {
      NfcTag tag = nfc.read(); // read the NFC tag
      String scannedUID = tag.getUidString(); // get the NFC tag's UID
 
      if( myUID.compareTo(scannedUID) == 0) // comparaison de la clef du périphérique scanné avec la clef "autorisée"
      {
         Serial.println("Clef correcte");
         monServo.attach(ServoPin);   // "Allumage" du servomoteur
         FlexiTimer2::stop();
         monServo.write(180);         // Ouverture de la serrure
         FlexiTimer2::start();
         digitalWrite(LedPin,HIGH);
         
      }
      
      else{
         Serial.print("Clef incorrecte");
         Serial.println(scannedUID);
         monServo.attach(ServoPin);   // "Allumage" du servomoteur
         FlexiTimer2::stop();
         monServo.write(0);           // Fermeture de la serrure
         FlexiTimer2::start();
      }
    }
}

void fermer() {
  unsigned long t = millis();
  if (t-lastDebounceTime > debounceDelay) {
    monServo.attach(ServoPin);   // "Allumage" du servomoteur
    FlexiTimer2::stop();
    monServo.write(0);           // Fermeture de la serrure
    FlexiTimer2::start();
    lastDebounceTime = t;
  }
}

void pause() {
  monServo.detach();    // "Extinction" du servomoteur
}

Carnet de bord